EXCELでスピーカーシミュレーション（８） - シミュレーションのトビラ

８．インピーダンス特性を求める

８．インピーダンス特性を求める

８－１．インピーダンス特性を表す式の導出

　今回はスピーカーのインピーダンス特性をシミュレーションしてみます。何のインピーダンスかというと、アンプ側からみたドライバーユニットの電気インピーダンスです。この電気インピーダンスから振動系の共振周波数や共振の大きさを知ることができるのですが、機械インピーダンスと違って実際の実験で簡単に測定できるので、理論計算できるようにしておくと便利です。
　ドライバーユニットのボイスコイルは、部品としては電気回路でいうインダクタのようなコイルですので、そのインピーダンスとしては直流抵抗とインダクタンスを持っています。したがって、ボイスコイルそのもののインピーダンスとしては、 $R_c+j \omega L_c$ のインピーダンスを持つことになりますので、周波数ごとに求めればインピーダンス特性が得られます。
　しかし、ドライバーユニットには磁気回路があり、しかも振動板と結合しているためボイスコイルは磁界の中を振動します。この振動が電気的なインピーダンスに影響をあたえることになるため、振動系を含めて立式する必要があります。
　ドライバーユニットの機械的な釣り合いと電気的な釣り合いに関する式(22)を再掲します。

$\begin{cases} 0 &= -BLI+(z+z_0)V \\ E &= BLV + (Z+Z_0)I \end{cases} \tag{22}$
　粒子速度を求めるときには、この連立方程式を $V$ について解きました。電気的なインピーダンス特性を求めるには、インピーダンスによって影響を受ける電流 $I$ について解きます。
　まず $V$ を消すために、上の式を移項します。
$V=\dfrac{BLI}{z+z_0}$
　これを下の式に代入します。
$\begin{align} E&=\dfrac{(BL)^2I}{z+z_0}+(Z+Z_0)I \\ &= \left \{ \dfrac{(BL)^2}{z+z_0}+(Z+Z_0) \right \} I \\ \therefore I &= \dfrac{1}{ \dfrac{(BL)^2}{z+z_0}+(Z+Z_0) }E \end{align}$
　インピーダンスは、電圧を電流で除したものですので、
$\begin{align} Z&=\dfrac{E}{I} \\ \therefore Z &=\dfrac{(BL)^2}{z+z_0}+(Z+Z_0) \tag{30} \end{align}$
　これが、インピーダンス特性を表す基本式です。等価回路を再掲します。

　粒子速度 $V$ を求めるときには、左側の電気回路を右側の機械回路に統合することと等価でしたが、今回は、右側の機械回路部分を左側の電気回路に統合することと等価です。
　早速、ドライバーユニットを無限大バッフルにつけた場合の各インピーダンスを代入してみます。式(30)の $z+z_0$ は、等価回路における機械インピーダンス(放射インピーダンス含む)の合成インピーダンスで、 $Z+Z_0$ は、ボイスコイルのインピーダンスとアンプの出力インピーダンス(ゼロですが)です。それぞれ代入すると下記の式になります。
$Z=\dfrac{ (BL)^2}{j \omega (m+m_a)+(r+r_a)+\frac{s}{j \omega} } +(R_c + j \omega L_c) \tag{31}$

８－２．各エンクロージャのインピーダンス特性を表す式の導出

　次に、密閉型、位相反転型、ドロンコーン型の各エンクロージャの場合のインピーダンス特性を求めてみたいと思います。

８−２−１．密閉型エンクロージャ

　密閉型エンクロージャの場合は、機械インピーダンス $z$ にキャビネット内空気のスチフネスと機械抵抗が加わるだけです。なので、ドライバーユニットのインピーダンスの式(31)における、スチフネス $s$ と機械抵抗 $r+r_a$ に、キャビネットのスチフネス $s_c$ と、機械抵抗 $r_c$ を足すので、

$Z= \dfrac{ (BL)^2}{j \omega (m+m_a)+(r+r_c+r_a)+\frac{s+s_c}{j \omega} } +(R_c + j \omega L_c) \tag{32}$
となります。

８−２−２．位相反転型エンクロージャ

　位相反転型エンクロージャの場合は、式(30)の $z+z_0$ に、各機械インピーダンスの合成インピーダンスを代入します。位相反転型エンクロージャでは、ドライバーユニット部分 $z_1$ とキャビネット部分 $z_2$ とは直列でしたが、キャビネット部分 $z_2$ とポート部分 $z_3$ とは並列回路として表されました。そのため、合成インピーダンスは、

$z_t = z_1+\dfrac{z_2z_3}{z_2+z_3}$
となります。ただし、
$\begin{align} z_1 &= j \omega (m+m_a)+(r+r_a)+\frac{s}{j \omega} \\ z_2 &=\frac{s_c}{j \omega}+r_c \\ z_3 &= \left ( \dfrac{S_d}{S_p} \right )^2 \{ j \omega(m_p+m_{ap})+(r_p+r_{ap}) \} \end{align}$
ですので、この $z_t$ を式(30)の $z+z_0$ と置き換えて、
$Z =\dfrac{(BL)^2}{z_t}+R_c+j \omega L_c \tag{33}$
となります。

８−２−３．ドロンコーン型エンクロージャ

　ドロンコーン型エンクロージャの場合は、位相反転型エンクロージャにおけるポート部分の質量 $m_p$ 、放射質量 $m_{ap}$ 、機械抵抗 $r_p$ 、放射抵抗 $r_{ap}$ が、ドロンコーンのスチフネス $s_d$ 、機械抵抗 $r_d$ 、放射質量 $m_{ad}$ 、放射抵抗 $r_{ad}$ に置き換わるだけですので、合成インピーダンスは、

$Z =\dfrac{(BL)^2}{z_t}+R_c+j \omega L_c \tag{34}$
となります。ただし、
$\begin{align} z_t &= z_1+\dfrac{z_2z_3}{z_2+z_3} \\ z_1 &= j \omega (m+m_a)+(r+r_a)+\frac{s}{j \omega} \\ z_2 &=\frac{s_c}{j \omega}+r_c \\ z_3 &= \left ( \dfrac{S_d}{S_{dc}} \right )^2 \{ j \omega m_{ad}+(r_{dc}+r_{ad})+\frac{s_d}{j \omega} \} \end{align}$
です。

８－３．EXCELでシミュレーションする

８－３－１．ドライバーユニットのインピーダンス

　前回の音圧のシミュレーションに続いて入力していきます。実は各インピーダンスはすでに入力済みですので、セルBG2に、

=IMSUM( IMDIV( ( $B$2*$B$3)^2,IMSUM( L2,$B$9,$B$11,M2)),$B$5,IMPRODUCT( I2,$B$6))
と入力してオートフィルします。
　なお、ドライバーユニットを単体で測定する場合には、振動板の前後がバッフル板で仕切られていないので、放射質量 $m_a$ と放射抵抗 $r_a$ は振動板前後の空気により2倍としなければ合いませんのでご注意。この計算ではバッフル板に取り付けてある条件で計算しています。
　音圧のときと同じく、複素数で表されていますので、絶対値をとると単位 $\Omega$ の値が出ます。セルBH2に、
=IMABS( BG2)
と入力してオートフィルします。

　列BHをグラフにとるとこのようになります。

　95Hz付近ではインピーダンスが極端に大きくなっています。これは、振動板を含む振動系が共振する周波数であり、ボイスコイルの振幅が増大することで磁気回路によってアンプが電流を流そうとするのを妨げるためです。この部分を動インピーダンスとよびます。また、高周波数になるほど徐々にインピーダンスが増加する傾向にありますが、これはボイスコイルが持つインダクタンスによるものです。

８－３－２．密閉型エンクロージャのインピーダンス

　次に密閉型エンクロージャのインピーダンスを入力します。セルBI2に、

=IMSUM( IMDIV( ( $B$2*$B$3)^2,IMSUM( L2,$B$9,$B$11,$B$15,M2,U2)),$B$5,IMPRODUCT( I2,$B$6))
と入力してオートフィルします。$B$15とU2が増えただけです。セルBJ2には絶対値を計算してオートフィルします。

　これをグラフにとって、ドライバーユニットと比較するとこのようになります。

　キャビネットのスチフネスと機械抵抗が増えたことで、共振周波数が高い方にずれ、ピークの値も若干下がっています。

８－３－３．位相反転型エンクロージャのインピーダンス

　次に位相反転型エンクロージャのインピーダンスを入力します。計算がややこしいので、まず、列BK～列BNに、 $z_1$ 、 $z_2$ 、 $z_3$ 、 $z_t$ をそれぞれ入力します。
　セルBK2には、

=IMSUM( L2,M2,$B$9,$B$11)
　セルBL2には、
=IMSUM( U2,$B$15)
　セルBM2には、
=IMPRODUCT( $B$23,IMSUM( AB2,$B$20,$B$22))
　セルBN2には、
=IMSUM( BK2,IMDIV( IMPRODUCT( BL2,BM2),IMSUM( BL2,BM2)))
　と入力し、セルBO2に、
=IMSUM( IMDIV( ( $B$2*$B$3)^2,BN2),$B$5,IMPRODUCT( I2,$B$6))
　と入力してオートフィルします。絶対値は列BPに計算します。

　これをグラフにとると、このようになります。

　ピークが2か所立っていると思います。もともとのドライバーユニットの共振周波数はより高い方に移動していますが、50Hz付近の低い周波数にポート内の空気の共振によるピークが立っています。ポートの直径や長さを変更することで、ポートの共振周波数を調整することができます。

８－３－4．ドロンコーン型エンクロージャのインピーダンス

　最後にドロンコーン型エンクロージャのインピーダンスを入力します。こちらも、まず、列BQに、 $z_3'$ を入力します。 $z_1$ と $z_2$ は列BKと列BLを流用できますので、列BRに $z_t'$ を入力します。
　セルBQ2には、

=IMPRODUCT( $B$31,IMSUM( AR2,AS2,$B$28,$B$30))
　セルBR2には、
=IMSUM( BK2,IMDIV( IMPRODUCT( BL2,BQ2),IMSUM( BL2,BQ2)))
　と入力し、セルBS2に、
=IMSUM( IMDIV( ( $B$2*$B$3)^2,BR2),$B$5,IMPRODUCT( I2,$B$6))
　と入力してオートフィルします。絶対値は列BTに計算します。

　これをグラフにとると、このようになります。

　こちらも位相反転型エンクロージャと同様に、ドライバーユニットの振動系による共振と、ドロンコーンの振動系による共振の2つのピークが立つことがわかります。

　このように、インピーダンス特性を見ると、振動系の共振周波数を具体的に把握することができます。ダイナミック型のスピーカーは共振周波数が低域の限界周波数を決めることになりますので、共振周波数を把握することは重要です。EXCELでこのインピーダンス特性が計算できるようになれば、具体的にどの要素をどれだけ調整すれば所望の共振周波数となるのかをシミュレーションできるようになります。

前へ　７．EXCELでシミュレーションする
 次へ　９．ダブルバスレフ型エンクロージャ